• Global variables

  function plus_two(n) {
      result = n + 2;
      return result;
  }

• The with block

  var foo = 5;
  with (obj)
      foo; // 5, unless obj.foo exists

• Wtf is the deal with the == operator?

  23 == "23";  // yes, of course a number is the same as a string

What happened?

• Time constraints?
• Corporate interference?
• Crack cocaine?
• Agile coaches?

• Assigning to global variables throws a ReferenceError
• The with statement no longer exists.
• But it's still JavaScript…

server.listen(function(request, response) {
    database.open(function(connection) {
        connection.query("SELECT * FROM posts", function(cursor) {
            cursor.fetchAll(function(posts) {
                response.write(posts.forEach(function(post) {
                    return post.title;
                }));
            });
        });
    });
});

// wtf

• CoffeeScript has significant indentation.

  if (name != "honey badger") {
    care()
  } else {
    eat_cobra()
  }

  becomes

  if name != "honey badger"
    care()
  else
    eat_cobra()

  Obvious, right?

• A function in JavaScript:

  var sum = function(a, b) {
      return a + b;
  }

• In CoffeeScript:

  sum = (a, b) -> a + b

• function(a, b) becomes (a, b) ->
• function() becomes simply ->
• return is implied: a function always returns the value of its last expression.

• Parentheses are optional:

  sum = (a, b) -> a + b
  
  sum(2, 3) # returns 5
  sum 2, 3  # returns 5

• Except when calling a function with no arguments:

  connection.close() # calls the close function
  connection.close   # returns the function, doesn't call it

• All variable declarations are local:

  foo = "bar"
  # compiles to:
  var foo;
  foo = "bar";

• No more == weirdness:

  2 == "2"
  # compiles to:
  2 === "2" # returns false, like you'd expect

• There is no with statement.

• In JavaScript:

  var tweet = {
      user: {
          name: "bodil",
          url: "http://bodil.github.com/"
      },
      text: "PONIES RULE SO HARD"
  };

• In CoffeeScript:

  tweet =
    user:
      name: "bodil"
      url: "http://bodil.github.com/"
    text: "PONIES RULE SO HARD"

• In JavaScript:

  var things_that_rule = [
      "robot unicorns",
      "honey badgers",
      "Lord Inglip"
  ];

• In CoffeeScript:

  things_that_rule = [
      "robot unicorns"
      "honey badgers"
      "Lord Inglip"
  ]

• Assign variables from inside arrays:

  sum_and_difference = (a, b) -> [ a + b, a - b]
  [ sum, difference ] = sum_and_difference 5, 2
  sum # returns 7
  difference # returns 3
  

• The if statement:

  if elvis.state == "alive"
    console.log "Hail to the King!"
  else
    console.log "You lie!"

• It has a short form:

  if power_level > 9000 then attack() else despair()

• It can even be used as a suffix:

  reign_in_graceland() if name == "Elvis"

• The basic loop:

  while count > 0
    count -= 1

• until is like while not:

  until power_level > 9000
    power_level += 1

• And you can put them after a statement, just like if:

  power_level++ while power_level <= 9000

• if works like the ternary operator:

  foo = false
  result = if foo then "foo is truthy" else "foo is falsy"
  # result is "foo is falsy"

• while returns an array:

  counter = 0
  list = while counter < 5
    counter++
    "n" + counter
  # list is [ 'n1', 'n2', 'n3', 'n4', 'n5' ]

• Even switch statements return something:

  result = switch request.error_code
    when 200 then "OK"
    when 301 then "don't live here anymore"
    when 404 then "not found"
    when 500 then "i maed u a page... but i eated it"
    else "unknown error call the police " + request.error_code
  

• Chained comparisons:

  if 20 < temperature < 30
    venture_outside()

• The existential operator:

  foo = { bar: "bar" }
  if foo?.bar then console.log foo.bar
  # if (foo != null && foo.bar) { ... }

• Tired of adding strings together? We borrowed this from Ruby:

  pokemon = "Snorlax"
  console.log "Wild #{pokemon} appeared!"
  => "Wild Snorlax appeared!"

• It's not just variable lookup, you can put real code in there:

  pokemon = "Snorlax"
  console.log "Wild #{pokemon.toUpperCase()} appeared!"
  => "Wild SNORLAX appeared!"

• Want to make really large strings? CoffeeScript doesn't mind line breaks:

  blurb = "I don't always drink beer,
           but when I do,
           I prefer Dos Equis."
  console.log blurb
  "I don't always drink beer, but when I do, I prefer Dos Equis."

• Or use heredocs to maintain formatting and stop worrying about escaping quotes:

  html = """
         <div class="article">
           <h1>Honey Badger</h1>
           <p>Honey Badger don't care.</p>
         </div>
         """

• Proper slicing operators:

  numbers = [ 0, 1, 2, 3, 4, 5, 6, 7, 8, 9 ]
  
  numbers[3..6] # [ 3, 4, 5, 6 ]
  numbers[7..]  # [ 7, 8, 9 ]
  numbers[..3]  # [ 0, 1, 2, 3 ]

• And we can do splicing too:

  numbers = [ 0, 1, 2, 3, 4, 5, 6, 7, 8, 9 ]
  
  numbers[3..6] = [ "foo", "bar" ]
  numbers # [ 0, 1, 2, "foo", "bar", 7, 8, 9 ]
                

• Iterate over a list's members:

  numbers = [ 1, 2, 3, "many" ]
  for number in numbers
    console.log "I just counted to #{number}"

• It has a suffix form too, of course:

  numbers = [ 1, 2, 3, "many" ]
  console.log "I just counted to #{number}" for number in numbers

• And it returns a new list:

  numbers = [ 1..5 ]
  result = for number in numbers
    number + 1
  result # [ 2, 3, 4, 5, 6 ]

Concise syntax for map and filter operations:

( expression for item in array )
( expression for item in array when condition )

( expression for key, value of object )
( expression for key, value of object when condition )

Have you ever tried to make JavaScript act object oriented?

Shape = function(x, y) {
    this.x = x;
    this.y = y;
};

Shape.prototype.centre = function() {
    return [ this.x, this.y ];
};

Shape.prototype.area = function() {
    return 0;
};

var point = new Shape(13, 37);

• In your web page:

  <script type="text/javascript" src="coffee-script.js"></script>
  
  <script type="text/coffeescript" src="my.coffee"></script>

• In Node:

  $ npm install coffee-script

  var my_cs_module = require("./my_cs_module");

• Compile and run anywhere JavaScript runs:

  $ coffee -c my_script.coffee